<%
	'****************************************************************
	'* 함수설명 : 업로드 컴포넌트 설정
	'* 변수설명 : component = 컴포넌트 (1 : ABC, 2 : DEXT)
	'*            maxSize = 최대 업로드 사이즈
	'*            defaultPath = 기본 저장경로
	'****************************************************************
	Function setUploadComponent(component, maxSize, defaultPath, codePage)
		Dim UPLOAD
		Select Case component
			Case "1"
				Set UPLOAD = Server.Createobject("ABCUpload4.XForm")
				UPLOAD.AbsolutePath = True
				UPLOAD.MaxUploadSize = 1024 * 1024 * maxSize
				UPLOAD.Overwrite = False
			Case "2"
				Set UPLOAD = Server.Createobject("DEXT.FileUpload")
				UPLOAD.MaxFileLen = 1024 * 1024 * maxSize
				UPLOAD.DefaultPath = defaultPath
				If Len(codePage) > 0 Then
					UPLOAD.CodePage = codePage
				End If
		End Select
		Set setUploadComponent = UPLOAD
	End Function
	
	'****************************************************************
	'* 함수설명 : 파일유무 체크 함수
	'* 변수설명 : strPath     = 파일의 경로
	'****************************************************************
	Function FileExists(strPath)
		Dim objFSO
		FileExists = False

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.FileExists(strPath) Then
			FileExists = True
		End If
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 파일 정보 반환 함수
	'* 변수설명 : strPath = 파일의 경로
	'****************************************************************
	Function GetFile(strPath)
		Dim objFSO
		GetFile = False
		
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		IF objFSO.FileExists(strPath) then
			Set GetFile = objFSO.GetFile(strPath)
		End IF
		Set objFSO = nothing
	End Function

	'****************************************************************
	'* 함수설명 : 파일 리스트 함수
	'* 변수설명 : strPath     = 파일의 경로
	'****************************************************************
	Function Files(strPath)
		Set Files = GetFolder(strPath).Files
	End Function

	'****************************************************************
	'* 함수설명 : 파일복사 함수
	'* 변수설명 : strSourcePath     = 원본파일의 경로
	'*            strTargetPath		= 대상파일의 경로
	'*            bitOverwrite		= 덮어쓰기
	'****************************************************************
	Function CopyFile(strSourcePath, strTargetPath, bitOverwrite)
		Dim objFSO
		CopyFile = False
		
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		IF objFSO.FileExists(strSourcePath) And Not(objFSO.FileExists(strTargetPath)) Then
			CopyFile = objFSO.CopyFile(strSourcePath, strTargetPath, bitOverwrite)
		End If
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 파일이동 함수
	'* 변수설명 : strTargetPath     = 대상파일의 경로
	'*            strMovePath		= 파일의 이동경로
	'****************************************************************
	Function MoveFile(strTargetPath, strMovePath)
		Dim objFSO
		MoveFile = False
		
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		IF objFSO.FileExists(strTargetPath) And Not(objFSO.FileExists(strMovePath)) Then
			MoveFile = objFSO.MoveFile(strTargetPath, strMovePath)
		End If
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 파일 삭제 함수
	'* 변수설명 : strPath     = 파일의 경로
	'****************************************************************
	Function DeleteFile(strPath)
		Dim objFSO
		DeleteFile = False

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.FileExists(strPath) Then
			DeleteFile = objFSO.DeleteFile(strPath)
		End If
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 폴더유무 체크 함수
	'* 변수설명 : strPath     = 폴더의 경로
	'****************************************************************
	Function FolderExists(strPath)
		Dim objFSO
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.FolderExists(strPath) Then FolderExists = True Else FolderExists = False
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 폴더 생성 함수
	'* 변수설명 : strPath = 생성할 폴더 경로 및 폴더명
	'****************************************************************
	Function CreateFolder(strPath)
		Dim objFSO
		CreateFolder = False
		
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If Not(objFSO.FolderExists(strPath)) Then
			CreateFolder = objFSO.CreateFolder(strPath)
		End If
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 폴더 삭제 함수
	'* 변수설명 : strPath = 경로
	'****************************************************************
	Function DeleteFolder(strPath)
		Dim objFSO
		DeleteFolder = False

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If (objFSO.FolderExists(strPath)) Then
			DeleteFolder = objFSO.DeleteFolder(strPath)
		End If
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 폴더 이동 함수
	'* 변수설명 : strTargetPath     = 대상파일의 경로
	'*            strMovePath		= 파일의 이동경로
	'****************************************************************
	Function MoveFolder(strTargetPath, strMovePath)
		Dim objFSO
		FolderMove = False
		
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		IF objFSO.FolderExists(strTargetPath) And Not(objFSO.FolderExists(strMovePath)) Then
			MoveFolder = objFSO.MoveFolder(strTargetPath, strMovePath)
		End If
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 폴더 정보 반환 함수
	'* 변수설명 : strPath = 경로
	'****************************************************************
	Function GetFolder(strPath)
		Dim objFSO
		GetFolder = False
		
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		IF objFSO.FolderExists(strPath) then
			Set GetFolder = objFSO.GetFolder(strPath)
		End IF
		Set objFSO = nothing
	End Function

	'****************************************************************
	'* 함수설명 : 폴더 리스트 반환 함수
	'* 변수설명 : strPath = 경로
	'****************************************************************
	Function SubFolders(strPath)
		Dim objFSO, Folders
		SubFolders = False
		
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		IF objFSO.FolderExists(strPath) then
			Set Folders = objFSO.GetFolder(strPath)
			Set SubFolders = Folders.SubFolders
			Set Folders = nothing
		End IF
		Set objFSO = nothing
	End Function

	'****************************************************************
	'* 함수설명 : 폴더 크기 반환 함수
	'* 변수설명 : strPath = 경로
	'****************************************************************
	Function GetFolderSize(strPath)
		Dim objFSO, Folders, Size
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		Set Folders = objFSO.GetFolder(strPath)
		Size = Folders.Size
		GetFolderSize = Size
		Set objFSO = Nothing
		Set Folders = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 드라이브유무 체크 함수
	'* 변수설명 : strDrive     = 드라이브
	'****************************************************************
	Function DriveExists(strDrive)
		Dim objFSO
		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.DriveExists(strDrive) Then DriveExists = True Else DriveExists = False
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 드라이브 정보 함수
	'* 변수설명 : strDrive = 드라이브
	'****************************************************************
	Function GetDrive(strDrive)
		Dim objFSO
		GetDrive = False

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.DriveExists(strDrive) Then
			Set GetDrive = objFSO.GetDrive(strDrive)
		End If
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 드라이브 정보 함수
	'****************************************************************
	Function Drives()
		Dim objFSO
		GetDrive = False

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		Set Drives = objFSO.Drives
		Set objFSO = Nothing
	End Function

	'****************************************************************
	'* 함수설명 : 드라이브 이름 반환 함수
	'* 변수설명 : strPath = 경로
	'****************************************************************
	Function GetDriveName(strPath)
		Dim objFSO

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		GetDriveName = objFSO.GetDriveName(strPath)
		Set objFSO = nothing
	End Function

	'****************************************************************
	'* 함수설명 : 파일 아이콘 반환
	'* 변수설명 : strFileName = 파일명
	'****************************************************************
	Function GetFileIcon(strFileName)
		Dim strFileExt
		If strFileName = False Then
			GetFileIcon = ""
		Else
			strFileExt = Mid(strFileName, InStrRev(strFileName, "."))
			strFileExt = Replace(strFileExt, ".", "")
			Select Case Lcase(strFileExt)
				Case "ai", "alz", "asf", "asp", "bmp", "cgi", "dll", "doc", "exe", "fla", "fon", "gIf", "hlp", "htm", "hwp", "img", "jpg", "js", "mid", "mov", "mp3", "mpg", "pcx", "pdf", "php3", "png", "ppt", "psd", "rar", "reg", "swf", "tIf", "ttf", "txt", "url", "wal", "wav", "wsz", "xls", "zip"
					GetFileIcon = strFileExt & ".gIf"
				Case Else GetFileIcon = ""
			End Select
		End If
	End Function

	'****************************************************************
	'* 함수설명 : 파일 사이즈 체크
	'* 변수설명 : intSize = 파일크기
	'****************************************************************
	Function GetFilesize(intSize)
		If intSize <> "" And Isnull(intSize) = False Then
			If Int(intSize) > 1024000 Then
				GetFilesize = Round((intSize / 1024000) * 1000 / 1000) & " MB"
			ElseIf Int(intSize) > 1024 Then
				GetFilesize = Round((intSize / 1024) * 10 / 10) & " KB"
			Else
				GetFilesize = intSize & " Byte"
			End If
		End If
	End Function

	'****************************************************************
	'* 함수설명 : 중복파일 체크
	'* 변수설명 : strPath     = 파일을 저장할 경로
	'*            strFileName = 저장할 파일명
	'****************************************************************
	Function CheckSameFile(strPath, strFileName)
		Dim objFSO, strFileNameOnly, strFileExt

		strFileName = Replace(strFileName, " ", "_")
		strFileName = Replace(strFileName, "%", "")

		If Right(strPath,1) <> "\" Then strPath = strPath &"\"

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.fileExists(strPath & strFileName) Then
			If InStrRev(strFileName, ".") <> 0 Then
				strFileNameOnly = Left(strFileName,InstrRev(strFileName, ".")-1)
				strFileExt = Mid(strFileName, InStrRev(strFileName, "."))
			Else
				strFileNameOnly = strFileName
				strFileExt = ""
			End If

			Dim i
			i = 0
			Do While (1)
				strFileName = strFileNameOnly & "[" & i & "]" & strFileExt
				If Not objFSO.fileExists(strPath & strFileName) Then Exit Do
				i = i + 1
			Loop
		End If
		Set objFSO = Nothing
		CheckSameFile = strFileName
	End Function

	'****************************************************************
	'* 함수설명 : 유니크 파일명 구하기
	'* 변수설명 : strFileName    = 파일명
	'****************************************************************
	Function GetUniqueFileName(strFileName)
		Dim FileExt, strTime, RndSerial

		If InStrRev(strFileName, ".") <> 0 Then FileExt = Mid(strFileName, InStrRev(strFileName, ".")) Else FileExt = ""

		Randomize
		strTime = datepart("h",Now) & Right("0" & datepart("n",Now),2) & Right("0" & datepart("s",Now),2)
		RndSerial = Int((899999 * Rnd) + 100000)
		GetUniqueFileName = strTime & RndSerial & FileExt
	End Function

	'****************************************************************
	'* 함수설명 : 업로드 불가 파일타입 체크
	'* 변수설명 : strFileName    = 파일명
	'****************************************************************
	Function CheckNotUploadFile(strFileName)
		Dim FileExe
		FileExe = Replace(Mid(strFileName, InStrRev(strFileName, ".") + 1), ".", "")
		Select Case UCase(FileExe)
			Case "ASP", "PHP", "JSP", "CGI", "ASA"
				CheckNotUploadFile = False
			Case Else
				CheckNotUploadFile = True
		End Select
	End Function

	'****************************************************************
	'* 함수설명 : 파일타입 체크
	'* 변수설명 : strType = 형태 (1:이미지, 2:음악)
	'*            strFileName = 파일명
	'****************************************************************
	Function CheckFileType(strType,strFileName)
		Dim FileExe
		FileExe = Replace(Mid(strFileName, InStrRev(strFileName, ".") + 1), ".", "")
		CheckFileType = False
		Select Case strType
			Case "1"
				Select Case UCase(FileExe)
					Case "JPG", "GIF", "BMP", "PNG", "TIF"
						CheckFileType = True
				End Select
			Case "2"
				Select Case UCase(FileExe)
					Case "MP3", "WAV", "MID", "WMA", "ASF", "ASX"
						CheckFileType = True
				End Select
		End Select
	End Function

	'****************************************************************
	'* 함수설명 : 파일타입 체크(사용자 정의)
	'* 변수설명 : strTypes = 예(JPG,GIF,BMP)
	'*            strFileName = 파일명
	'****************************************************************
	Function CheckFileTypeDefine(strTypes, strFileName)
		Dim FileExe, arrType, j
		FileExe = Replace(Mid(strFileName, InStrRev(strFileName, ".") + 1), ".", "")
		CheckFileTypeDefine = False

		arrType = Split(strTypes, ",")
		For j = 0 To Ubound(arrType)
			If UCase(Trim(arrType(j))) = UCase(FileExe) Then
				CheckFileTypeDefine = True
				Exit For
			End If
		Next
	End Function

	'****************************************************************
	'* 함수설명 : 이미지 리사이징
	'* 변수설명 : strFlag = normal, crop, canvas
	'*            inFilePath = 원본 파일경로
	'*            outFilePath = 저장경로
	'*            intWidth = 리사이징 너비
	'*            intHeight = 리사이징 높이
	'*            intQuality = 품질
	'****************************************************************
	Sub ImageResizeCreate(strFlag, inFilePath, outFilePath, intWidth, intHeight, intQuality)
		Dim objImg: Set objImg = Server.CreateObject("ImageMagickObject.MagickImage.1")

		Dim strOriImageWH, arrOriImageWH, intOriWidth, intOriHeight
		strOriImageWH = objImg.IdentIfy("-format", "%w|%h", inFilePath)
		If Len(strOriImageWH) > 2 Then
			arrOriImageWH = Split(strOriImageWH, "|")
			intOriWidth = arrOriImageWH(0)
			intOriHeight = arrOriImageWH(1)
		End If

		If intOriWidth <> intWidth Or intOriHeight <> intHeight Then
			If UCase(strFlag) = "CROP" Then
				If Trim(intQuality) = "" Or isNull(Trim(intQuality)) Then
					objImg.Convert inFilePath, "-resize", intWidth &"x"& intHeight &"^", "-gravity", "center", "-extent", intWidth &"x"& intHeight, outFilePath
				Else
					objImg.Convert inFilePath, "-resize", intWidth &"x"& intHeight &"^", "-gravity", "center", "-extent", intWidth &"x"& intHeight, "-quality="& intQuality, outFilePath
				End If
			ElseIf UCase(strFlag) = "CANVAS" Then
				If Trim(intQuality) = "" Or isNull(Trim(intQuality)) Then
					objImg.Convert inFilePath, "-resize", intWidth &"x"& intHeight &">", "-gravity", "center", "-extent", intWidth &"x"& intHeight, outFilePath
				Else
					objImg.Convert inFilePath, "-resize", intWidth &"x"& intHeight &">", "-gravity", "center", "-extent", intWidth &"x"& intHeight, "-quality="& intQuality, outFilePath
				End If
			Else
				If Trim(intQuality) = "" Or isNull(Trim(intQuality)) Then
					objImg.Convert inFilePath, "-resize", intWidth &"x"& intHeight &">", outFilePath
				Else
					objImg.Convert inFilePath, "-resize", intWidth &"x"& intHeight &">", "-quality="& intQuality, outFilePath
				End If
			End If
		Else
			Call CopyFile(inFilePath, outFilePath, true)
		End If

		Set objImg = Nothing
	End Sub

	'****************************************************************
	'* 함수설명 : 이미지 섬네일 생성
	'* 변수설명 : strFilePath = 원본 파일경로
	'*            strThumbFlag = 섬네일 생성방법(normal, crop, canvas)
	'*            strThumbType = 섬네일 구분명 예(big,middle,small,140x140)
	'*            intThumbWidth = 섬네일 너비
	'*            intThumbHeight = 섬네일 높이
	'****************************************************************
	Sub ImageThumbCreate(strFilePath, strThumbFlag, strThumbType, intThumbWidth, intThumbHeight)
		Dim arrFileFolder, strFileName, strFileNameOnly, strFileExt, strThumbName, strThumbFolder
		Dim strOutFilePath, objFSO, i

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.FileExists(strFilePath) Then
			arrFileFolder = Split(strFilePath,"\")
			If UBound(arrFileFolder) > 0 Then
				strFileName = arrFileFolder(UBound(arrFileFolder))

				strFileNameOnly = Left(strFileName,InstrRev(strFileName, ".")-1)
				strFileExt = Mid(strFileName, InStrRev(strFileName, "."))
				strThumbName = strFileNameOnly &"_"& strThumbType & strFileExt

				arrFileFolder(UBound(arrFileFolder)) = ""
				strThumbFolder = Join(arrFileFolder,"\") &"thumb\"
				strOutFilePath = strThumbFolder & strThumbName

				Call CreateFolder(strThumbFolder)
				Call ImageResizeCreate(strThumbFlag, strFilePath, strOutFilePath, intThumbWidth, intThumbHeight, 70)
			End If
		End If
		Set objFSO = Nothing
	End Sub

	'****************************************************************
	'* 함수설명 : 이미지 섬네일 삭제
	'* 변수설명 : strFilePath = 원본 파일경로
	'*            strThumbTypes = 섬네일 구분명 (구분명|구분명|구분명|.....)
	'****************************************************************
	Sub ImageThumbDelete(strFilePath, strThumbTypes)
		Dim arrFileFolder, strFileName, strFileNameOnly, strFileExt
		Dim arrThumbTypes, i, strDelFilePath

		arrFileFolder = Split(strFilePath,"\")
		strFileName = arrFileFolder(UBound(arrFileFolder))
		strFileNameOnly = Left(strFileName,InstrRev(strFileName, ".")-1)
		strFileExt = Mid(strFileName, InStrRev(strFileName, "."))
		arrFileFolder(UBound(arrFileFolder)) = ""

		arrThumbTypes = Split(strThumbTypes, "|")
		For i=0 To UBound(arrThumbTypes)
			strDelFilePath = Join(arrFileFolder,"\") &"thumb\" & strFileNameOnly &"_"& arrThumbTypes(i) & strFileExt
			Call DeleteFile(strDelFilePath)
		Next
	End Sub

	'****************************************************************
	'* 함수설명 : 이미지 섬네일명
	'* 변수설명 : strFileUrl = 원본 파일 URL
	'*            strThumbType = 섬네일 구분명 예(big,middle,small,140x140)
	'****************************************************************
	Function ImageThumbUrl(strFileUrl, strThumbType)
		Dim arrFileFolder, strFileName, strFileNameOnly, strFileExt

		On Error Resume Next

		arrFileFolder = Split(strFileUrl,"/")
		strFileName = arrFileFolder(UBound(arrFileFolder))
		strFileNameOnly = Left(strFileName,InstrRev(strFileName, ".")-1)
		strFileExt = Mid(strFileName, InStrRev(strFileName, "."))
		arrFileFolder(UBound(arrFileFolder)) = ""

		If Err.number = 0 Then
			ImageThumbUrl = Join(arrFileFolder,"/") &"thumb/" & strFileNameOnly &"_"& strThumbType & strFileExt
		Else
			ImageThumbUrl = ""
		End If
	End Function

	'****************************************************************
	'* 함수설명 : 파일 다운로드
	'* 변수설명 : component = 컴포넌트 (1 : ABC, 2 : DEXT)
	'*            strFilePath = 파일경로(파일명포함)
	'*            strFileName = 파일명(다운로드 파일명)
	'****************************************************************
	Sub FileDownLoad(component,strFilePath,strFileName)
		Dim strUserAgent, strContentDisp, strContentType
		Dim objFSO, objF, objDownload, objStream

		strUserAgent = Request.ServerVariables("HTTP_USER_AGENT")
		If InStr(strUserAgent, "MSIE") > 0 THEN
			If InStr(strUserAgent, "MSIE 5.0") > 0 THEN
				strContentDisp = "attachment;filename="
				strContentType = "application/x-msdownload"
			Else
				strContentDisp = "attachment;filename="
				strContentType = "application/unknown"
			End If
		Else
			strContentDisp = "attachment;filename="
			strContentType = "application/unknown"
		End If

		Select Case component
			Case "2"
				Response.Buffer = False
				Response.AddHeader "Content-Disposition", strContentDisp & Server.URLPathEncode(strFileName)
				'// IIS7.5 에서 "Content-Length" 오류발생
				'Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
				'Set objF = objFSO.GetFile(strFilePath)
				'Response.AddHeader "Content-Length", objF.Size
				'Set objF = Nothing
				'Set objFSO = Nothing
				Response.ContentType = strContentType
				Response.CacheControl = "public"
				Response.Charset = "utf-8"
				 
				Set objDownload = Server.CreateObject("DEXT.FileDownload")
				objDownload.Download strFilePath
				Set objDownload = Nothing

			Case Else
				Response.Buffer = False
				Response.AddHeader "Content-Disposition", strContentDisp & Server.URLPathEncode(strFileName)
				Response.ContentType  = strContentType
				Response.CacheControl = "public"
				Response.Charset = "utf-8"
			 
				Set objStream = Server.CreateObject("ADODB.Stream")
				objStream.Open
				objStream.Type = 1
				objStream.LoadFromFile strFilePath
				Response.BinaryWrite objStream.Read
				Response.Flush

				objStream.Close
				Set objStream = Nothing
		End Select
	End Sub

	'****************************************************************
	'* 함수설명 : 에디터 파일 삭제
	'* 변수설명 : intDbRow = DB 로우 카운트
	'*            arrDbRows = DB 파일정보
	'****************************************************************
	Sub EditorFileDelete(intDbRow, arrDbRows)
		If intDbRow > -1 Then
			Dim i, strFilePath, strFileName
			For i=0 To intDbRow
				strFilePath = Replace(arrDbRows(0,i), "/", "\")
				strFileName = arrDbRows(1,i)

				strFilePath = ConstEditorRoot & strFilePath & strFileName
				DeleteFile strFilePath
			Next
		End If
	End Sub

	'****************************************************************
	'* 함수설명 : 엑셀파일 시트명 리스트
	'* 변수설명 : strFilePath = 엑셀파일경로
	'****************************************************************
	Function excelSheetNames(strFilePath)
		Dim objFSO, strConn, excelConn, Sheets, intRow, arrRows
		Dim strSheets, i
		Err.clear
		'on error resume next
		strSheets = "" : intRow = 0

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.FileExists(strFilePath) Then
			strConn = "Provider=Microsoft.ACE.OLEDB.12.0; Data Source="& strFilePath &"; Mode=ReadWrite|Share Deny None; ExtEnded Properties='Excel 12.0;HDR=YES;IMEX=1'; Persist Security Info=False"

			Set excelConn = Server.CreateObject("ADODB.Connection")
			excelConn.Open strConn

			Set Sheets = excelConn.OpenSchema(20)
			arrRows = Sheets.getrows
			intRow = UBound(arrRows, 2)
			Sheets.Close
			Set Sheets = Nothing

			excelConn.Close
			Set excelConn = Nothing

			If intRow > -1 Then
				For i=0 To intRow
					If arrRows(2,i) <> "_xlnm#Print_Titles" Then
						If Len(strSheets) > 0 Then strSheets = strSheets &"|"
						strSheets = strSheets & Replace(Trim(arrRows(2,i)), "$", "")
					End If
				Next
			End If
		End If
		Set objFSO = Nothing

		excelSheetNames = Split(strSheets, "|")
	End Function

	'****************************************************************
	'* 함수설명 : 엑셀파일 쿼리
	'* 변수설명 : strFilePath = 엑셀파일경로, strSheetName = 엑셀시트명
	'*            intRow = 로우수, arrRows = 로우데이터(배열)
	'****************************************************************
	Sub excelQuery(strFilePath, strSheetName, intRow, arrRows)
		Dim objFSO, strConn, strSql, Rs
		Err.clear
		'on error resume next
		intRow = 0

		Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
		If objFSO.FileExists(strFilePath) Then
			strConn = "Provider=Microsoft.ACE.OLEDB.12.0; Data Source="& strFilePath &"; Mode=ReadWrite|Share Deny None; ExtEnded Properties='Excel 12.0;HDR=YES;IMEX=1'; Persist Security Info=False"
			strSql = "SELECT * FROM ["& strSheetName &"$]"

			Set Rs = Server.CreateObject("Adodb.Recordset")
			Rs.Open strSql, strConn, 0, 1
			arrRows = Rs.getrows
			intRow = UBound(arrRows, 2)
			Rs.Close
			Set Rs = Nothing
		End If
		Set objFSO = Nothing
		If Err.number > 0 Then intRow = -1
	End Sub

	'****************************************************************
	'* 데이터 경로
	'****************************************************************
	'// 파일저장 경로
	Dim ConstMainDataRoot, ConstMainDataUrl
	ConstMainDataUrl = "/upfile"
	ConstMainDataRoot = Server.MapPath(ConstMainDataUrl)

		'//온라인상담
		Dim ConstConsultDataRoot, ConstConsultDataUrl
		ConstConsultDataUrl = ConstMainDataUrl &"/consult"
		ConstConsultDataRoot = Server.MapPath(ConstConsultDataUrl)

			'//온라인상담 > 답변
			Dim ConstCslAnsDataRoot, ConstCslAnsDataUrl
			ConstCslAnsDataUrl = ConstConsultDataUrl &"/answer"
			ConstCslAnsDataRoot = Server.MapPath(ConstCslAnsDataUrl)

		'//상담위원 관련
		Dim ConstCounselorRoot, ConstCounselorUrl
		ConstCounselorUrl = ConstMainDataUrl &"/bizLicense"
		ConstCounselorRoot = Server.MapPath(ConstCounselorUrl)

		'//에디터 관련
		Dim ConstEditorRoot, ConstEditorUrl
		ConstEditorUrl = ConstMainDataUrl &"/editor"
		ConstEditorRoot = Server.MapPath(ConstEditorUrl)

		'//실무강의
		Dim ConstLectureDataRoot, ConstLectureDataUrl
		ConstLectureDataUrl = ConstMainDataUrl &"/lecture"
		ConstLectureDataRoot = Server.MapPath(ConstLectureDataUrl)
		
		'//회계 동영상 관리
		Dim ConstMediaDataRoot, ConstMediaDataUrl
		ConstMediaDataUrl = ConstMainDataUrl &"/media"
		ConstMediaDataRoot = Server.MapPath(ConstMediaDataUrl)

%>